2.7. Wat is het aantal vrijwilligers?

Concepten

• Vestiging
• Vestigingsnummer
• Vrijwilligersovereenkomst
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• heeft opdrachtnemer
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.7
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    ?Periode
13    (?vestiging AS ?Indeling)
14    (COUNT (DISTINCT ?persoon) AS ?Aantal_vrijwilligers)
15
16WHERE {
17    # BIND(2024 AS ?jaar)
18
19    # Kwartaal-selector + totaal jaar (0)
20    VALUES ?kw { 0 1 2 3 4 }
21
22    # Periodegrenzen
23    BIND( xsd:date(CONCAT(STR(?jaar), "-",
24            IF(?kw=2,"04-01", 
25            IF(?kw=3,"07-01", 
26            IF(?kw=4,"10-01", "01-01")))
27        )) AS ?p_start ) .
28    BIND( xsd:date(CONCAT(STR(?jaar), "-",
29            IF(?kw=1,"03-31", 
30            IF(?kw=2,"06-30", 
31            IF(?kw=3,"09-30", "12-31")))
32        )) AS ?p_eind ) .
33
34    BIND( IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode ) .
35    
36    ?overeenkomst 
37        a onz-pers:VrijwilligersOvereenkomst ;
38        onz-pers:heeftOpdrachtnemer ?persoon ;
39        onz-g:hasPart ?overeenkomst_afspraak .
40    ?overeenkomst_afspraak
41        a onz-pers:WerkOvereenkomstAfspraak ;
42        onz-g:startDatum ?start_afspraak .
43    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
44    FILTER(?start_afspraak <= ?p_eind && ((?eind_afspraak >= ?p_start) || (!BOUND(?eind_afspraak))))
45
46    ?overeenkomst_afspraak onz-g:isAbout ?locatie . 
47    {
48        ?locatie onz-g:partOf* ?vestiging_uri . 
49        ?vestiging_uri a onz-org:Vestiging ; 
50            onz-g:identifiedBy ?vest_nr ; 
51            onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 . 
52        ?vest_nr a onz-org:Vestigingsnummer ; 
53            onz-g:hasDataValue ?vestiging .
54        BIND( IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode) .
55        ?pc_gebied onz-g:identifiedBy ?postcode ; 
56            onz-g:partOf+ ?zk_regio . 
57        ?zk_regio a onz-org:ZorgkantoorRegio . 
58    } UNION {
59        ?locatie onz-g:partOf* ?vestiging_uri . 
60        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri . 
61        BIND( "Totaal organisatie" AS ?vestiging) .
62    }
63}
64
65GROUP BY ?Periode ?vestiging
66ORDER BY ?vestiging ?Periode